ubuntu 12.04 64bitでWin32をクロスコンパイル5

ubuntu 12.04 64bitでWin32をクロスコンパイル4 のつづき

で表題改　ubuntu 12.04 64bitでWin64をクロスコンパイル

多分最終章

Ubuntuの上でqtをwin64クロスコンパイルする環境はすべて整った。
とりあえず４でつくった64bitのQtを/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/にmvします。
つまり
/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/bin
/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/include
/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/lib
のところにそれぞれのファイルがコピーされます

そしてmkspecを64bit用に作成
cd /usr/share/qt4/mkspecs/
sudo cp -rf win32-x-g++ win64-x-g++
cd win64-x-g++
sudo  vi qmake.conf

編集内容は以下の通り
#
# qmake configuration for win32-g++
#
# Written for MinGW
#

MAKEFILE_GENERATOR    = MINGW
TEMPLATE        = app
CONFIG            += qt warn_on release link_prl copy_dir_files debug_and_release debug_and_release_target precompile_header
QT            += core gui
DEFINES            += UNICODE QT_LARGEFILE_SUPPORT
QMAKE_COMPILER_DEFINES  += __GNUC__ WIN32

QMAKE_EXT_OBJ           = .o
QMAKE_EXT_RES           = _res.o

QMAKE_CC        = x86_64-w64-mingw32-gcc 
QMAKE_LEX        = flex
QMAKE_LEXFLAGS        =
QMAKE_YACC        = byacc
QMAKE_YACCFLAGS        = -d
QMAKE_CFLAGS        =
QMAKE_CFLAGS_DEPS    = -M
QMAKE_CFLAGS_WARN_ON    = -Wall
QMAKE_CFLAGS_WARN_OFF    = -w
QMAKE_CFLAGS_RELEASE    = -O2
QMAKE_CFLAGS_DEBUG    = -g
QMAKE_CFLAGS_YACC    = -Wno-unused -Wno-parentheses

QMAKE_CXX        = x86_64-w64-mingw32-g++
QMAKE_CXXFLAGS        = $$QMAKE_CFLAGS
QMAKE_CXXFLAGS_DEPS    = $$QMAKE_CFLAGS_DEPS
QMAKE_CXXFLAGS_WARN_ON    = $$QMAKE_CFLAGS_WARN_ON
QMAKE_CXXFLAGS_WARN_OFF    = $$QMAKE_CFLAGS_WARN_OFF
QMAKE_CXXFLAGS_RELEASE    = $$QMAKE_CFLAGS_RELEASE
QMAKE_CXXFLAGS_DEBUG    = $$QMAKE_CFLAGS_DEBUG
QMAKE_CXXFLAGS_YACC    = $$QMAKE_CFLAGS_YACC
QMAKE_CXXFLAGS_THREAD    = $$QMAKE_CFLAGS_THREAD
QMAKE_CXXFLAGS_RTTI_ON    = -frtti
QMAKE_CXXFLAGS_RTTI_OFF    = -fno-rtti
QMAKE_CXXFLAGS_EXCEPTIONS_ON = -fexceptions -mthreads
QMAKE_CXXFLAGS_EXCEPTIONS_OFF = -fno-exceptions

QMAKE_INCDIR        = /usr/x86_64-w64-mingw32/include
QMAKE_INCDIR_QT        = /home/kokawa2003/.wine/drive_c/Qt64/4.8.1/include
QMAKE_LIBDIR_QT        = /home/kokawa2003/.wine/drive_c/Qt64/4.8.1/lib

QMAKE_RUN_CC        = $(CC) -c $(CFLAGS) $(INCPATH) -o $obj $src
QMAKE_RUN_CC_IMP    = $(CC) -c $(CFLAGS) $(INCPATH) -o $@ $<
QMAKE_RUN_CXX        = $(CXX) -c $(CXXFLAGS) $(INCPATH) -o $obj $src
QMAKE_RUN_CXX_IMP    = $(CXX) -c $(CXXFLAGS) $(INCPATH) -o $@ $<

QMAKE_LINK        = x86_64-w64-mingw32-g++  
QMAKE_LINK_C        = x86_64-w64-mingw32-gcc 
QMAKE_LFLAGS        = -mthreads -Wl,-enable-stdcall-fixup -Wl,-enable-auto-import -Wl,-enable-runtime-pseudo-reloc -mwindows
QMAKE_LFLAGS_EXCEPTIONS_ON = -mthreads
QMAKE_LFLAGS_EXCEPTIONS_OFF =
QMAKE_LFLAGS_RELEASE    = -Wl,-s
QMAKE_LFLAGS_DEBUG    =
QMAKE_LFLAGS_CONSOLE    = -Wl,-subsystem,console
QMAKE_LFLAGS_WINDOWS    = -Wl,-subsystem,windows
QMAKE_LFLAGS_DLL        = -shared
QMAKE_LINK_OBJECT_MAX    = 10
QMAKE_LINK_OBJECT_SCRIPT= object_script
QMAKE_PREFIX_STATICLIB  = lib
QMAKE_EXTENSION_STATICLIB = a


QMAKE_LIBS        =
QMAKE_LIBS_CORE         = -lole32 -luuid -lws2_32 -ladvapi32 -lshell32 -luser32 -lkernel32
QMAKE_LIBS_GUI          = -lgdi32 -lcomdlg32 -loleaut32 -limm32 -lwinmm -lwinspool -lws2_32 -lole32 -luuid -luser32 -ladvapi32
QMAKE_LIBS_NETWORK      = -lws2_32
QMAKE_LIBS_OPENGL       = -lglu32 -lopengl32 -lgdi32 -luser32
QMAKE_LIBS_COMPAT       = -ladvapi32 -lshell32 -lcomdlg32 -luser32 -lgdi32 -lws2_32
QMAKE_LIBS_QT_ENTRY     = -lmingw32 -lqtmain

!isEmpty(QMAKE_SH) {
    MINGW_IN_SHELL      = 1
    QMAKE_DIR_SEP        = /
    QMAKE_QMAKE        ~= s,\\\\,/,
    QMAKE_COPY        = cp
        QMAKE_STREAM_EDITOR     = sed
    QMAKE_COPY_DIR        = cp -r
    QMAKE_MOVE        = mv
    QMAKE_DEL_FILE        = rm
    QMAKE_MKDIR        = mkdir -p
    QMAKE_DEL_DIR        = rmdir
    QMAKE_CHK_DIR_EXISTS = test -d
} else {
    QMAKE_COPY        = copy /y
    QMAKE_COPY_DIR        = xcopy /s /q /y /i
    QMAKE_MOVE        = move
    QMAKE_DEL_FILE        = del
    QMAKE_MKDIR        = mkdir
    QMAKE_DEL_DIR        = rmdir
    QMAKE_CHK_DIR_EXISTS    = if not exist
}

QMAKE_MOC        = $$[QT_INSTALL_BINS]$${DIR_SEPARATOR}moc
QMAKE_UIC        = $$[QT_INSTALL_BINS]$${DIR_SEPARATOR}uic
QMAKE_IDC        = $$[QT_INSTALL_BINS]$${DIR_SEPARATOR}idc

QMAKE_IDL        = midl
QMAKE_LIB        = x86_64-w64-mingw32-ar  -ru
QMAKE_RC        = x86_64-w64-mingw32-windres
QMAKE_ZIP        = zip -r -9

QMAKE_STRIP        = x86_64-w64-mingw32-strip
QMAKE_STRIPFLAGS_LIB     += --strip-unneeded
load(qt_config)


ここまででで環境構築終了
Qtのプロジェクトをtestqtとするとき
qmake -spec win64-x-g++ testqt.pro
make　
で64bit のEXEができます。
file testqt.exe
で64bitを確認してください。


実行には
/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/bin/QtCore4.dll .
/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/bin/QtDeclarative4.dll .
/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/bin/QtGui4.dll .
/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/bin/QtNetwork4.dll .
/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/bin/QtScript4.dll .
/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/bin/QtSql4.dll .
/home/kokawa2003/.wine/drive_c/Qt64/4.8.1/bin/QtXmlPatterns4.dll .
/usr/lib/gcc/x86_64-w64-mingw32/4.6/libgcc_s_sjlj-1.dll .
/usr/lib/gcc/x86_64-w64-mingw32/4.6/libstdc++-6.dll .
が私の場合は必要でした。（すべて64bitで揃える）  

上のdllをexeのローカルにコピーのあと
wine testqt.exe
で見事64bitのexeが起動します。